Построение и установка в режимах Debug и Release, Не получается :( Опции

[igor_bogomolov]

Всем привет.

По описанию создаю такой блок в .pro- файле

Раскрывающийся текст

TARGET   = k095_client
DESTDIR  = $$PWD/bin

CONFIG += debug_and_release
CONFIG += build_all
CONFIG(debug, debug|release) {
    DEFINES += "APP_TITLE=\\\"k095_client_debug\\\""
    DESTDIR = $$join(DESTDIR,,,/debug)
    unix:   TARGET = $$join(TARGET,,,_debug)
    win32:  TARGET = $$join(TARGET,,d)
    message(Debug build.   $$TARGET install in \"$$DESTDIR\")
} else {
    DEFINES += "APP_TITLE=\\\"k095_client\\\""
    DESTDIR = $$join(DESTDIR,,,/release)
    message(Release build.   $$TARGET install in \"$$DESTDIR\")
}

После компиляции, на самом деле, получаю k095_client и k095_client_debug в соответствующих директориях. Беда только в том, что в реальности это два совершенно одинаковых файла, собранных в релизе.

Как собрать одновременно отладочную и релизную сборки? И возможно ли это сделать в QtCreatore, что бы он не навязывал собственных правил?

[SABROG]

Насчет QtCreator'а ничего сказать не могу, а в консоли я собирал так:

mingw32-make all

[Litkevich Yuriy]

igor_bogomolov, у тебя объектные файлы сначала собираются отладочные, затем на основе них создаётся бинарь. При сборке релиза, т.к. объектники уже есть из них собирается бинарь (опять такой же только имя другое)

Я так поступаю, написал себе стандартный pri-файл (обрати внимание на OBJECTS_DIR)

stdconfig.pri

######################################################################
# Temporary directory
######################################################################
isEmpty(TMPDIR){
    TMPDIR = ./tmp
    message(Auto set TMPDIR = $${TMPDIR})
}


######################################################################
isEmpty(DESTDIR){
    DESTDIR = ./
    contains(TEMPLATE, lib){
        DESTDIR = ./lib
    }else{
        DESTDIR = ./build
    }
    message(Auto set DESTDIR = $${DESTDIR})
}

TMP_DIR = $$TMPDIR

CONFIG (debug, debug|release) {
    contains(TEMPLATE, lib){
        TARGET = $$qtLibraryTarget($$TARGET)
    }else{
        TARGET      = $$join(TARGET,,,.d)
    }
    OBJECTS_DIR = $${TMP_DIR}/debug
    CONFIG        += console
}else{
    OBJECTS_DIR = $${TMP_DIR}/release
}

UI_DIR      = $${TMP_DIR}/uic
MOC_DIR     = $${TMP_DIR}/moc
RCC_DIR        = $${TMP_DIR}/rcc

contains(CONFIG, debug_and_release) {
    CONFIG        += build_all
}


contains(DEBUGCONFIG, true){
    message(CONFIG = $${CONFIG})
    message(DESTDIR=$${DESTDIR})
    message(TARGET=$${TARGET})
    message(TMPDIR=$${TMPDIR})
    message(TMP_DIR=$${TMP_DIR})
    message(OBJECTS_DIR=$${OBJECTS_DIR})
    message(INCLUDEPATH = $${INCLUDEPATH})
    message(QMAKE_LIBDIR = $${QMAKE_LIBDIR})
    message(LIBS = $${LIBS})    
    message(===================================)
}

contains(HARDCODED, target) {
    TARGETTMP = '\\"$${TARGET}\\"'
    DEFINES  += TARGET=\"$${TARGETTMP}\"
}

Использую так

myproject.pro

TARGET = tomsk
TEMPLATE = app
DESTDIR = ..
TMPDIR = ../tmp
#DEBUGCONFIG = true
#HARDCODED = target

CONFIG += debug_and_release
#CONFIG += console

#=========== Define ================
#unix:DEFINES   = 
#win32:DEFINES  = 


#=========== Files =================
HEADERS           +=    mainwindow.h 

SOURCES           +=    mainwindow.cpp 

SOURCES           +=    main.cpp


#========= Dependency ==============
DEPENDPATH       +=    .
INCLUDEPATH       +=    .

#        --- Qt ---
#QT += sql
#QT -= gui

#      --- External ---
#include($$(LIBS)/qextserialport_1.1/serialport.pri) 


#======== Translation ===============
#TRANSLATIONS    = app_en.ts
#CODECFORTR      = UTF-8


# ======== Convenient config ===============
include($$(LIBS)\myPri\stdconfig.pri)

здесь:
LIBS - переменная окружения содержащая путь, где лежат всякие либы и pri-файл
DEBUGCONFIG - позволяет управлять отладкой pro-файлов (см. pri-файл)
HARDCODED - позволяет зашить в бинарь всякие штуки (сейчас только имя целя, но хотел ещё и путь к переводам и ...)

[Litkevich Yuriy]

Последнее обновление

stdconfig.pri

######################################################################
# HowTo USE
######################################################################
# In pro-file:
# TEMPDIR - set Temporary Directory (optionale)
# DESTDIR - set Destination Directory (optionale)
# TRDIR - set Translations Directory (optionale) 
#
# DEBUGCONFIG = false  - off pro-file debuging  (optionale)
#
# HARDCODED += <name> - hardcoded (defined) <name> in DEFINE  (optionale)
#    here is <name> suported:
#        target            - #define TARGET = $${TARGET}
#        translationdir    - #define TRDIR = $${TRDIR}
#        version         - #define VERSION = $${VERSION}
#
# include($$(LIBS)/MyPri/stdconfig.pri)
#
#
######################################################################



#=========== Temporary directory ========
isEmpty(TEMPDIR){
    isEmpty(TMPDIR){
        TMPDIR = ./tmp
        message(Auto set TEMPDIR = $${TMPDIR})
    }
}else{
    TMPDIR = $$TEMPDIR
}

TMP_DIR = $$TMPDIR

#=========== Destination directory ========
isEmpty(DESTDIR){
    DESTDIR = ./
    contains(TEMPLATE, lib){
        DESTDIR = ./lib
    }else{
        DESTDIR = ./build
    }
    message(Auto set DESTDIR = $${DESTDIR})
}




#=========== Terget Name ========
TS_BASENAME = $${TARGET}

CONFIG (debug, debug|release) {
    contains(TEMPLATE, lib){
        TARGET = $$qtLibraryTarget($$TARGET)
    }else{
        TARGET      = $$join(TARGET,,,.d)
    }
    OBJECTS_DIR = $${TMP_DIR}/debug
    # Console added in debug mode
    CONFIG        += console
}else{
    OBJECTS_DIR = $${TMP_DIR}/release
}

#=========== Std pathes ========
UI_DIR      = $${TMP_DIR}/uic
MOC_DIR     = $${TMP_DIR}/moc
RCC_DIR        = $${TMP_DIR}/rcc

#=========== build all if debug_and_release ========
contains(CONFIG, debug_and_release) {
    CONFIG        += build_all
}


#================== HARDCODED NAMES ===============
contains(HARDCODED, target) {
    TARGETTMP = '\\"$${TARGET}\\"'
    DEFINES  += TARGET=\"$${TARGETTMP}\"
}

contains(HARDCODED, translationdir) {
    isEmpty(TRDIR){
        TRDIR = $$DESTDIR
        message(Auto set TRDIR = $${TRDIR})
    }
    TRDIR_TMP = '\\"$${TRDIR}\\"'
    DEFINES  += TRDIR=\"$${TRDIR_TMP}\"

}

contains(HARDCODED, translations) {
    isEmpty(TRDIR){
        TRDIR = $$DESTDIR
        message(Auto set TRDIR = $${TRDIR})
    }
    TRDIR_TMP = '\\"$${TRDIR}\\"'
    DEFINES  += TRDIR=\"$${TRDIR_TMP}\"

    TS_BASENAME_TMP = '\\"$${TS_BASENAME}\\"'
    DEFINES  += TS_BASENAME=\"$${TS_BASENAME_TMP}\"
    

}

contains(HARDCODED, version) {
    isEmpty(VERSION){
        error (Version is HARDCODED but is Empty)
    }else{
        VER_TMP = '\\"$${VERSION}\\"'
        DEFINES  += VERSION=\"$${VER_TMP}\"
    }
}
#========= Makefile Target fo preprocessoring =======
#topreprocessor1.target    = %.i
#topreprocessor1.depends    = $(MAKEFILE).Debug FORCE
#topreprocessor1.commands    = $(MAKE) -f $(MAKEFILE).Debug $@

#QMAKE_EXTRA_TARGETS       += topreprocessor1

#CONFIG (debug, debug|release) {
#    topreprocessorcpp.target    = %.i
#    topreprocessorcpp.depends    = %.cpp
#    topreprocessorcpp.commands    = $(CXX) -E $(CXXFLAGS) $(INCPATH) $< -o $@
#    QMAKE_EXTRA_TARGETS       += topreprocessorcpp

#    topreprocessorh.target    = %.i
#    topreprocessorh.depends    = %.h
#    topreprocessorh.commands    = $(CXX) -E $(CXXFLAGS) $(INCPATH) $< -o $@
#    QMAKE_EXTRA_TARGETS       += topreprocessorh

#    toprprocessorc.target    = %.i
#    toprprocessorc.depends    = %.c
#    toprprocessorc.commands    = $(CXX) -E $(CXXFLAGS) $(INCPATH) $< -o $@
#    QMAKE_EXTRA_TARGETS       += toprprocessorc
#}
#=================== DEBUG PRI ======================
!contains(DEBUGCONFIG, false){
    message("If you no need debug pri-file, then write next: DEBUGCONFIG = false")
    message(CONFIG = $${CONFIG})
    message(DESTDIR=$${DESTDIR})
    message(TARGET=$${TARGET})
    message(QMAKE_TARGET=$${QMAKE_TARGET})
    
    message(TMPDIR=$${TMPDIR})
    message(TRDIR=$${TRDIR})
    message(OBJECTS_DIR=$${OBJECTS_DIR})
    message(INCLUDEPATH = $${INCLUDEPATH})
    message(QMAKE_LIBDIR = $${QMAKE_LIBDIR})
    message(LIBS = $${LIBS})
    !isEmpty(HARDCODED){
        message(HARDCODED = $${HARDCODED})
        message(DEFINES = $${DEFINES})
    }    
    message(===================================)
}